SQL Server存储过程入门案例详解
存储过程是存储于数据库中的一组T-SQL语句。有了存储过程之后，与数据库的交互就没有必要在程序中写一堆的SQL语句，而只需用一条语句调用适当的存储过程来完成就可以了。另外，由于代码是存储在数据库中，我们也可以在不同的应用程序或查询窗口中不断的重复利用那些代码。下面将讲述一些简单的例子，它们将说明如何构造和使用存储过程。
下面的例子将简单的说明如何创建存储过程。以下所有例子均使用AdventureWorks数据库。其它的数据库和应用程序可以依此类推。
例 1 – 简单的存储过程
这个简单的存储过程将实现如下功能：从Person.Contact表中取出第一条记录。
CREATE PROCEDURE uspGetContact
AS
SELECT TOP 1 ContactID, FirstName, LastName
FROM Person.Contact
创建完上面的语句后，使用下面的命令可以执行该存储过程。
EXEC uspGetContact
查询的结果如下：
例 2 – 带参数的存储过程
这个例子在上个例子的基础上做了一点修改：传入了一个参数，根据传入的参数来查询相应的记录。为了更好地利用上面的例子，这次我们就不用重新再创建一个存储过程了，而是使用ALTER PROCEDURE(注意：不是CREATE PROCEDURE)来修改例1中已经创建好的存储过程。代码如下：
ALTER PROCEDURE uspGetContact @LastName NVARCHAR(50)
AS
SELECT TOP 1 ContactID, FirstName, LastName
FROM Person.Contact
WHERE LastName = @LastName
下面显示了运行存储过程的2种不同方法。第一种方法仅仅传入了我们想要的参数值。而第二种方法包含了参数名和参数值。任意一种方法都可以运行该例中的存储过程。
EXEC uspGetContact 'Alberts'
EXEC uspGetContact @LastName='Alberts'
查询结果如下：
例 3 – 带输入和输出参数的存储过程
这个例子中既有输入参数也有输出参数。在存储过程中查询后得到的ContactID可以利用输出参数进行回传。回传参数用户查询人员表中的其他字段，如ContactID、FirstName、LastName以及这个人的任何地址记录。
首先，我们按如下方式修改存储过程uspGetContact。其次，运行下面代码执行该存储过程。最后，基于传回的值可以查询人员的姓名和地址等信息。
ALTER PROCEDURE uspGetContact @LastName NVARCHAR(50), @ContactID INT output
AS
SELECT TOP 1 @ContactID = c.ContactID
FROM HumanResources.Employee a
INNER JOIN HumanResources.EmployeeAddress b ON a.EmployeeID = b.EmployeeID
INNER JOIN Person.Contact c ON a.ContactID = c.ContactID
INNER JOIN Person.Address d ON b.AddressID = d.AddressID
WHERE c.LastName = @LastName
存储过程修改后，运行如下代码将执行该存储过程。如果ContactID有值，就会返回人员和地址信息。
DECLARE @ContactID INT
SET @ContactID = 0
EXEC uspGetContact @LastName='Smith', @ContactID=@ContactID OUTPUT
IF @ContactID <> 0
BEGIN
SELECT ContactID, FirstName, LastName
FROM Person.Contact
WHERE ContactID = @ContactID
SELECT d.AddressLine1, d.City, d.PostalCode
FROM HumanResources.Employee a
INNER JOIN HumanResources.EmployeeAddress b ON a.EmployeeID = b.EmployeeID
INNER JOIN Person.Contact c ON a.ContactID = c.ContactID
INNER JOIN Person.Address d ON b.AddressID = d.AddressID
WHERE c.ContactID = @ContactID
END
查询结果如下：
例 4 – 使用RAISERROR 语句的存储过程
在这个例子中，将把例3中的2个步骤整合到一个存储过程中。存储过程的第一步是取得ContactID，第二步是查询人员的姓名和地址信息。然后添加RAISERROR语句，如果查询不到记录则返回错误信息。
RAISERROR语句可以用来控制应用程序处理无数据或其它错误的方式。将该存储过程执行2次，看看能找到数据和不能找到数据的情况下各返回什么。
ALTER PROCEDURE uspGetContact @LastName NVARCHAR(50)
AS
DECLARE @ContactID INT
SELECT TOP 1 @ContactID = c.ContactID
FROM HumanResources.Employee a
INNER JOIN HumanResources.EmployeeAddress b ON a.EmployeeID = b.EmployeeID
INNER JOIN Person.Contact c ON a.ContactID = c.ContactID
INNER JOIN Person.Address d ON b.AddressID = d.AddressID
WHERE c.LastName = @LastName
IF @@ROWCOUNT > 0
BEGIN
SELECT ContactID, FirstName, LastName
FROM Person.Contact
WHERE ContactID = @ContactID
SELECT d.AddressLine1, d.City, d.PostalCode
FROM HumanResources.Employee a
INNER JOIN HumanResources.EmployeeAddress b ON a.EmployeeID = b.EmployeeID
INNER JOIN Person.Contact c ON a.ContactID = c.ContactID
INNER JOIN Person.Address d ON b.AddressID = d.AddressID
WHERE c.ContactID = @ContactID
END
ELSE
BEGIN
RAISERROR ('No record found',10,1)
END
EXEC uspGetContact @LastName='Walters'
查询结果如下：
EXEC uspGetContact @LastName='Job'
当第一步查询无数据时，整个存储过程的执行结果如下：
例 5 -调用存储过程的存储过程
这个例子中有2个存储过程。第一个存储过程uspFindContact查找第一条带有地址信息的记录并将ContactID返回给调用它的存储过程，然后显示人员和地址信息。
CREATE PROCEDURE uspFindContact @LastName NVARCHAR(50), @ContactID INT output
AS
SELECT TOP 1 @ContactID = c.ContactID
FROM HumanResources.Employee a
INNER JOIN HumanResources.EmployeeAddress b ON a.EmployeeID = b.EmployeeID
INNER JOIN Person.Contact c ON a.ContactID = c.ContactID
INNER JOIN Person.Address d ON b.AddressID = d.AddressID
WHERE c.LastName = @LastName
下面的代码对uspGetContact做了一点修改：调用uspFindContact并返回结果集。
ALTER PROCEDURE uspGetContact @LastName NVARCHAR(50)
AS
DECLARE @ContactID INT
SET @ContactID = 0
EXEC uspFindContact @LastName=@LastName, @ContactID=@ContactID OUTPUT
IF @ContactID <> 0
BEGIN
SELECT ContactID, FirstName, LastName
FROM Person.Contact
WHERE ContactID = @ContactID
SELECT d.AddressLine1, d.City, d.PostalCode
FROM HumanResources.Employee a
INNER JOIN HumanResources.EmployeeAddress b ON a.EmployeeID = b.EmployeeID
INNER JOIN Person.Contact c ON a.ContactID = c.ContactID
INNER JOIN Person.Address d ON b.AddressID = d.AddressID
WHERE c.ContactID = @ContactID
END
ELSE
BEGIN
RAISERROR ('No record found',10,1)
END
EXEC uspGetContact @LastName='Walters'
第一步查询结果如下：
EXEC uspGetContact @LastName='Job'
第一步查询结果如下：
例 6 -带评论的存储过程
最后这个例子基于存储过程uspGetContact，并增加了评论功能。展示了如何在一个存储过程中使用评论。存储过程中的评论有2种实现方式：1.使用-- 2.使用/*来作为评论的开始，以*/作为结束。其余部分和上面的例子一样。
ALTER PROCEDURE uspGetContact @LastName NVARCHAR(50)
AS
/* This is a sample stored procedure to show how comments work within a stored procedure */
-- declare variable
DECLARE @ContactID INT
-- set variable value
SET @ContactID = 0
-- execute stored proc and return ContactID value
EXEC uspFindContact @LastName=@LastName, @ContactID=@ContactID OUTPUT
-- if ContactID does not equal 0 then return data else return error
IF @ContactID <> 0
BEGIN
SELECT ContactID, FirstName, LastName
FROM Person.Contact
WHERE ContactID = @ContactID
SELECT d.AddressLine1, d.City, d.PostalCode
FROM HumanResources.Employee a
INNER JOIN HumanResources.EmployeeAddress b ON a.EmployeeID = b.EmployeeID
INNER JOIN Person.Contact c ON a.ContactID = c.ContactID
INNER JOIN Person.Address d ON b.AddressID = d.AddressID
WHERE c.ContactID = @ContactID
END
ELSE
BEGIN
RAISERROR ('No record found',10,1)
END
这些都是非常简单的例子，通过这些例子，希望能让大家知道：创建一个SQL Server的存储过程并不难。如果能够在查询窗口或者应用程序中得心应手的使用查询语句，那么按照上面的例子，也就能够非常容易的掌握存储过程的使用。