补：没办法；俺的cnit的博客发布不上去，就发在俺的cpp博客吧。
由于工作缘故，需要处理一接口发送来的xml串，对方采用java以字节流模式post一个xml串，
在asp中采用request估计把它加载到xml解析器中应该报无法解析。
采用Request.binaryRead 即可解决，但是要注意几个细节方面。
一一到来。
1. 读取字节流
Dim vtBody
iReceive = Request.TotalBytes
vtBody = Request.BinaryRead(iReceive)
2. 转换字节流为字符串，有以下几个函数可以任选。
' a。byte --> str ,该转换只适用小数据，但是所有ie没有问题，，，
Function bytes2BSTR(vIn)
strReturn = ""
For i = 1 To LenB(vIn)
ThisCharCode = AscB(MidB(vIn,i,1))
If ThisCharCode < &H80 Then
strReturn = strReturn & Chr(ThisCharCode)
Else
NextCharCode = AscB(MidB(vIn,i+1,1))
strReturn = strReturn & Chr(CLng(ThisCharCode) * &H100 + CInt(NextCharCode))
i = i + 1
End If
Next
bytes2BSTR = strReturn
End Function
'b。采用 ado record来转换，该转换速度快，转换数据大，据说对ie5支持不够好，
function rsbinarytostring(xbinary)
Dim binary
If vartype(xbinary)= 8 then
binary = multibytetobinary(xbinary)
Else
binary = xbinary
End If
Dim rs, lbinary
const adlongvarchar = 201
Set rs = createobject("adodb.recordset")
lbinary = lenb(binary)
If lbinary>0 Then
rs.fields.append "mbinary", adlongvarchar, lbinary
rs.open
rs.addnew
rs("mbinary").appendchunk binary
rs.update
rsbinarytostring = rs("mbinary").Value
rs.Close
Else
rsbinarytostring = ""
end if
End Function
'***************************************************
'c。采用流解析字符串，该转换速度快，转换数据大，据说对ie5支持不够好，
function stream_binarytostring(binary, charset)
set binarystream = createobject("adodb.stream")
'读入字节流
binarystream.type = 1
binarystream.open
binarystream.write binary
'内部以字符方式返回
binarystream.position = 0
binarystream.type = 2
If len(charset) > 0 Then
binarystream.charset = charset
Else
binarystream.charset = "us-ascii"
End If
stream_binarytostring = binarystream.readtext
end function
则调用上面任一个进行转换即可。如：
strBody = stream_binarytostring(vtBody, "utf-8")
3. 将strBody解码
如果调用Response.Write strBody ，则在ie上可以看到正常的xml结构体部分。
但是如果你要是写在文本中，你将会看到的是如下的样式：
%3C%3Fxml+version+%3D+%221.0%22+encoding%3D%22UTF-8%22+%3F%3E%3CROOT%3E%3CUSER%3Egtzx%3C%2FUSER%3E%3CPASS%3Egtzx%3C%2FPASS%3E%3CMO%3E%3CMOID%3E291AC5FDBD0DF4EF2B2A2950FB730610%3C%2FMOID%3E%3CMSGFORMAT%3E15%3C%2FMSGFORMAT%3E%3CCLASSID%3Ehttp%3A%。。。。%3E%3CSERVICEID%3E1981%3C%2FSERVICEID%3E%3CCITYID%3E102%3C%2FCITYID%3E%3CPROVINCEID%3E16%3C%2FPROVINCEID%3E%3CMOUSEID%3E2%3C%2FMOUSEID%3E%3CSPNUMBER%3E10666066%3C%2FSPNUMBER%3E%3CLINKID%3E%3C%2FLINKID%3E%3CREMARK%3E%3C%2FREMARK%3E%3C%2FMO%3E%3C%2FROOT%3E
这表示是url 编码方式，它把utf-8编码进行了再一次编码，如果你要是xml解析器来解析的话，恐怕它是干不了活的。（也许有，但是asp中玩那个xmldocument实在是不想研究下去）
不过再需要做个urlDecode转换，这个asp函数，网上一大把，搜出一个，粘贴下来就可以去掉%并转换utf-8格式。这里贴出一个修改的urlDecode函数，
'*****************************************************
'功能描述：URL解码码函数
'输入参数：vURL编码的字符串
'返回值：解码后的字符串
Public Function URLDecoding(sIn)
Dim s,i,l,c,t,n : s="" : l=Len(sIn)
For i=1 To l
c=Mid(sIn,i,1)
If c<>"%" Then
s = s & c
Else
c=Mid(sIn,i+1,2) : i=i+2 : t=CInt("&H" & c)
If t<&H80 Then
s=s & Chr(t)
Else
c=Mid(sIn,i+1,3)
If Left(c,1)<>"%" Then
URLDecoding=s
Exit Function
Else
c=Right(c,2) : n=CInt("&H" & c)
t=t*256+n-65536
s = s & Chr(t) : i=i+3
End If
End If
End If
Next
s=Replace(s, "+"," ")
URLDecoding=s
End Function
4. 调用xml解析器，加载以上字符串，即可解决。
'***********************************************************
'解析xml文件
'***********************************************************
Dim xml
Set xml = Server.CreateObject ("msxml2.DOMDocument")
xml.Async = False
xml.Loadxml(strBody)
5.读出xml中的节点，写入文本或者写入数据库，ok。
总结：
在asp中采用xmlhttp发送或者接收，是不考虑字节流模式发送的，直接调用xmlhttp中的send即可。管它是
按啥模式发送的，但是在其他语言编程中，比如java，c#，or vc中，有可能是按字节流方式发送出去的，那么，
如果想图个方便，直接用asp写个接口处理下，就要考虑下和其他程序处理的细节。