转移指令的原理
可以修改IP，或同时修改CS和IP的指令统称为转移指令。
概括以讲，转移指令就是可以控制CPU执行内存中某处的代码的指令。
8086CPU的转移行为有以下几类：
l 只修改IP时，称为段内转移，比如：jmp ax。
l 同时修改CS和IP时，称为段间转移，比如：jmp 1000:0。
由于转移指令对IP的修改范围不同，段内转换又分为：短转移和近转移。
l 短转移IP的修改范围为-128~127。
l 近转移IP的修改范围为-32768~32767。
8086CPU的转移指令分为以下几类：
l 无条件转移指令（如：jmp）
l 条件转移指令
l 循环指令（如：loop）
l 过程
l 中断
这些转移指令转移的前提条件可能不同，但转移的基本原理是相同的。
操作符offset
操作符offset在汇编语言中是由编译器处理的符号，它的功能是取得标号的偏移地址。如：
assume cs:codesg
codesg segment
start: mov ax, offset start ;相当于mov ax,0
s:mov ax, offset s ;相当于mov ax,3
codesg ends
end start
jmp指令
jmp为无条件转移指令，可以只修改IP，也可以同时修改CS和IP。
jmp指令要给出两种信息：
l 转移的目的地址
l 转移的距离（段间转移、段内短转移、段人近转移）
依据位移进行转移的jmp指令
jmp short 标号（转到标号处执行指令）
这种格式的jmp指令实现的是段内短转移，它对IP的修改范围为-128~127，也就是说，它向前转移时可以最多越过128个字节，向后转移可以最多越过127个字节。
jmp指令中的“short”符号，说明指令进行的是短转移。
jmp指令中的“标号”是代码段中的标号，指明了指令要转移的目的地，转移指令结束后，CS：IP应该指向标号处的指令。
比如：
assume cs:codesg
codesg segment
start: mov ax,0
mov bx,0
jmp short s
add ax,1
s: inc ax
codesg ends
end start
CPU在执行jmp指令的时候并不需要转移的目的地址。
在“jmp short 标号”指令所对应的机器码中，并不包含转移的目的地址，而包含的是转移的位移，这个位移，是编译器根据汇编指令中的“标号”计算出来的。
实际上，指令“jmp short 标号”的功能为：(IP)=(IP)+8位位移。
(1)8位位移=“标号”处的地址-jmp指令后的第一个字节的地址；
(2)short指明此处的位移为8位移；
(3)8位位移的范围为-128~127，用补码表示；
(4)8位位移由编译器在编译时算出。
还有一种和指令“jmp short 标号”功能相近的指令格式：jmp near prt 标号，它实现的是段内近转移。
指令“jmp near ptr 标号”的功能为：(IP)=(IP)+16位位移。
(1)16位位移=指令“标号”处的地址-jmp指令后的第一个字节的地址；
(2)near ptr指明此处的位移为16位位移，进行的是段内近转移；
(3)16位位移的范围为-32768~32767，用补码表示。
(4)16位位移由编译器程序在编译时算出。
转移的目的地址在指令中的jmp指令
前面讲的jmp指令，其对应的机器指令中并没有转移的目的地址，而是相对于当前IP的转移地址。
指令“jmp far ptr 标号”实现的是段间转移，又称为远转移。功能如下：
(CS)=标号所在段的段地址；（IP）=标号所在段中的偏移地址。
far ptr指明了指令用标号的段地址和偏移地址修改CS和IP。
转移地址在寄存器中的jmp指令
指令格式：jmp 16位寄存器
功能：(IP)=(16位寄存器)
转移地址在内存中的jmp指令
有两种格式：
（1） jmp word ptr 内存单元地址（段内转移）
功能：从内存单元地址处开始存放着一个字，是转移的目的偏移地址。
内存单元寺睛可用寻址方式的任一格式给出。比如：
mov ax,0123H
mov ds:[0],ax
jmp word ptr ds:[0]
执行后，（IP）=0123H。
又如：
mov ax,0123H
mov [bx],ax
jmp word ptr [bx]
执行后，(IP)=0123H
（2） jmp dword ptr 内存单元地址（段间转移）
功能：从内存单元地址处开始存放着两个字，高地址处的字是转移的目的段地址，低地址处是转移的目的偏移地址。
（CS）=（内存单元地址+2）
（IP）=（内存单元地址）
内存单元地址可用寻址方式的任一格式给出。如：
mov ax,0123H
mov ds:[0],ax
mov word ptr ds:[2],0
jmp dword ptr ds:[0]
执行后，（CS）=0，（IP）=0123H，CS：IP指向0000:0123。
又如，
mov ax,0123H
mov [bx],ax
mov word ptr [bx+2],0
jmp dword ptr [bx]
执行后，（CS）=0，（IP）=0123H，CS:IP指向0000:0123。
jcxz指令
jcxz指令为有条件转移指令，所有的有条件转移指令都是短转移，在对应的机器码中包含转移的位移，而不是目的地址。对IP的修改范围都为：-128~127。
指令格式：jcxz 标号（如果(cx)=0, 转移到标号处执行。）
操作：当（cx）=0时，（IP）=（IP）+8位位移；
8位位移=“标号”处的地址-jczx指令后的第一个字节的地址；
8位位移的范围为-128~127，用补码表示；
8位位移由编译器在编译时算出。
当（cx不等于0时），什么也不做（程序向下执行）。
指令“jcxz 标号”的功能相当于：
if (cx)==0 jmp short 标号；
loop指令
loop指令为循环指令，所有的循环指令都是短转移，在对应的机器码中包含转移的位移，而不是目的地址。对IP的修改范围都为：-128~127。
指令格式：loop 标号（（cx）=（cx）-1，如果(cx)≠0，转移到标号处执行。）
操作：（1）(cx)=(cx)-1
(2) 如果(cx)≠0，(IP)=(IP)+8位位移。
8位位移=“标号”处的地址-loop指令后的第一个字节的地址；
8位位移的范围为-128~127，用补码表示；
8位位移由编译器在编译时算出。
如果(cx)=0，什么也不做（程序向下执行）。
指令“loop 标号”的功能相当于：
(cx)--;
if ( (cx)≠0) jmp short 标号；
根据位移进行转移的意义
jmp short 标号
jmp near ptr 标号
jcxz 标号
loop 标号
它们对IP的修改是根据转移目的地址和转移起始地址之间的位移来进行的。
在它们对应的机器码中不包含转移的目的地址，而包含的是到目的地址的位移。
这种设计，方便了程序段在内存中的浮动装配。
编译器对转移位移超界的检测
根据位移进行转移的指令，它们在转移范围受到转移位移的限制，如果在源程序中出现了转移范围超界的问题，在编译的时候，编译器将报错。